100 REM  BASICVERSION DER DRUCKROUTINE
110 REM  KANN AUCH ALS UNTERROUTINE IN EIGENE PROGRAMME EINGEBAUT WERDEN
120 REM  ANPASSUNG AN ANDERE 7-NADEL-DRUCKER SICHER MOEGLICH
130 OPEN4,4:OPEN6,4,6:PRINT#6,CHR$(16):CLOSE6:POKE56,30
140 REM  OFFNET DRUCKKANAL UND STELLT ZEILENABSTANT FUER GRAFIK EIN
150 FOR I=319 TO-3 STEP -7
160 U$="":U2$="":O$="":O2$=""
170 FOR Y=0 TO199:C=128:G=128
180 FOR X=I TO I-2 STEP -1
190 A=0:GOSUB1000
200 BI=2*(I-X)
210 IFA=1THEN C=C+2^BI+2^(BI+1)
220 NEXTX
230 A=0:X=I-3:GOSUB1000
240 IF A=1THEN C=C+64 :G=G+1
250 FOR X=I-4 TO I-6 STEP -1
260 A=0:GOSUB1000
270 BI =2*(I-X-4)
280 IF A=1 THEN G=G+2^(BI+1)+2^(BI+2)
290 NEXTX
300 IF Y<100THENO$=O$+CHR$(C)+CHR$(C)
310 IF Y>99THENO2$=O2$+CHR$(C)+CHR$(C)
320 IF Y<100THENU$=U$+CHR$(G)+CHR$(G)
330 IF Y>99THENU2$=U2$+CHR$(G)+CHR$(G)
340 NEXTY
350 PRINT#4,CHR$(8)CHR$(27)CHR$(16)CHR$(0)CHR$(40);
360 PRINT#4,O$O2$CHR$(9)
370 REM  CHR$(8) STELLT BIT-MUSTER-MODUS EIN
380 REM  CHR$(27)CHR$(16)CHR$(0)CHR$(40) STELLT DIE DRUCKSTARTADRSSE JEDER
390 REM  ZEILE AUF 40 PUNKTE NACH RECHTS EIN
400 REM CHR$(9) STELLT DEN BIT-MUSTER-MODUS WIEDER AUS
410 PRINT#4,CHR$(8)CHR$(27)CHR$(16)CHR$(0)CHR$(40);
420 PRINT#4,U$U2$CHR$(9)
430 NEXTI
440 CLOSE4:END
450 REM  PRUEFROUTINE OB DER GRAFIKPUNKT GESETZT ODER NICHT GESETZT IST:
1000 IFX<0THENA=0:RETURN
1010 BY=(XAND504)+40*(YAND248)+(YAND7)
1020 BI=2^(7-(XAND7))
1030 S=PEEK(8192+BY)
1040 IF(SORBI)=STHENA=1
1050 RETURN